Dr3dweRkZ

Díky aktivitě ve vláknu Share With Your Fellow Geeks About Your Current JavaFX Activities jsem byl požádán o zveřejněni kódu k demu Streams. Kód který vidíte níže je bez jakýchkoliv úprav, tedy "as is" a je volně k dispozici čili "free to use".

package streams;

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.animation.Timeline;
import javafx.animation.KeyFrame;
import javafx.scene.paint.Color;
import javafx.scene.Node;
import javafx.util.Sequences;

/**
 * @author jiri
 */

var w = Wire {
    sy: 264, ey: 264
    ex: 512
};

var w1 = Wire {
    sy: 248, ey: 248
    color: Color.RED
};
var w2 = Wire {
    sy: 240, ey: 240
    color: Color.GREEN
};
var w3 = Wire {
    sy: 272, ey: 272
    color: Color.YELLOW
};

var w4 = Wire {
    sy: 256, ey: 256
    color: Color.WHITE
}

var wires: Node[] = [];

var master: Timeline = Timeline {
    keyFrames: [
        KeyFrame {
            time: 0s
            action: function(): Void {
                if (-1 == Sequences.indexByIdentity(wires, w4))
                    insert w4 into wires;
                w4.t.play();
            }

        }
        KeyFrame {
            time: 2s
            action: function(): Void {
                if (-1 == Sequences.indexByIdentity(wires, w3))
                    insert w3 into wires;
                w3.t.play();
            }
        }
        KeyFrame {
            time: 4s
            action: function(): Void {
                if (-1 == Sequences.indexByIdentity(wires, w2))
                    insert w2 into wires;
                w2.t.play();
            }
        }
        KeyFrame {
            time: 6s
            action: function(): Void {
                if (-1 == Sequences.indexByIdentity(wires, w1))
                    insert w1 into wires;
                w1.t.play();
            }
        }
        KeyFrame {
            time: 8s
            action: function(): Void {
                if (-1 == Sequences.indexByIdentity(wires, w))
                    insert w into wires;
                w.t.play();
            }
        }]
    repeatCount: Timeline.INDEFINITE
}
master.play();
//w.t.play();

Stage {
    title: "Streams"
    scene: Scene {
        width: 512
        height: 512
        fill: Color.BLACK
        content: bind wires
    }
}

Třída Wire.fx

package streams;

import javafx.scene.CustomNode;
import javafx.scene.Node;
import javafx.scene.Group;
import javafx.scene.shape.Path;
import javafx.scene.shape.MoveTo;
import javafx.scene.effect.MotionBlur;
import javafx.scene.effect.Reflection;
import javafx.scene.paint.Color;
import javafx.scene.shape.CubicCurveTo;
import javafx.animation.Timeline;
import javafx.animation.Interpolator;
import javafx.animation.KeyFrame;

/**
 * @author jiri
 */

public class Wire extends CustomNode {
    public var sy = 256;
    public var ey = 256;
    var fromY = sy - 64;
    var toY = sy + 64;
    var sx = 0;
    var cx1 = sy - 128;
    var cy1 = sy - 128;
    var cx2 = sy + 128;
    var cy2 = sy + 128;
    public var ex = 512;
    var seq = [fromY, toY, sy, ey, cy1, cy2, ex];
    public var color = Color.BLUE;
    public var time = 0s;
    public var thickness = 3;
    public var smooth = true;
    public override var opacity = .5;
    public override var effect = Reflection {input: MotionBlur {}};
    public var t: Timeline = Timeline {}  

    override protected function create () : Node {
        t = Timeline {
            keyFrames: [
                KeyFrame {
                    time: time
                    values: [
                        sy => seq[0] tween Interpolator.LINEAR,
                        cy1 => seq[2] tween Interpolator.LINEAR,
                        cy2 => seq[2] tween Interpolator.LINEAR,
                        ey => seq[1] tween Interpolator.LINEAR,
                        /*ex => 0 tween Interpolator.LINEAR*/]
                }
                KeyFrame {
                    time: time + 2s
                    values: [
                        fromY => seq[2] tween Interpolator.LINEAR,
                        cy1 => seq[5] tween Interpolator.LINEAR,
                        cy2 => seq[4] tween Interpolator.LINEAR,
                        toY => seq[3] tween Interpolator.LINEAR,
                        /*ex => 128 tween Interpolator.LINEAR*/]
                }
                KeyFrame {
                    time: time + 4s
                    values: [
                        sy => seq[1] tween Interpolator.LINEAR,
                        cy1 => seq[2] tween Interpolator.LINEAR,
                        cy2 => seq[2] tween Interpolator.LINEAR,
                        ey => seq[0] tween Interpolator.LINEAR,
                        /*ex => 256 tween Interpolator.LINEAR*/]
                }
                KeyFrame {
                    time: time + 6s
                    values: [
                        toY => seq[2] tween Interpolator.LINEAR,
                        cy1 => seq[4] tween Interpolator.LINEAR,
                        cy2 => seq[5] tween Interpolator.LINEAR,
                        fromY => seq[3] tween Interpolator.LINEAR,
                        /*ex => 384 tween Interpolator.LINEAR*/]
                }
                KeyFrame {
                    time: time + 8s
                    values: [
                        sy => seq[0] tween Interpolator.LINEAR,
                        cy1 => seq[3] tween Interpolator.LINEAR,
                        cy2 => seq[3] tween Interpolator.LINEAR,
                        ey => seq[1] tween Interpolator.LINEAR,
                        /*ex => 512 tween Interpolator.LINEAR*/]
                }]
            repeatCount: Timeline.INDEFINITE
        }
        //t.play();

        return Group {
            content: [
                Path {
                elements: [
                    MoveTo {
                        x: 0, y: bind sy
                    }
                    CubicCurveTo {
                        controlX1: bind cx1, controlY1: bind cy1
                        controlX2: bind cx2, controlY2: bind cy2
                        x: bind ex, y: bind ey
                    }]
                strokeWidth: bind thickness
                stroke: color
                smooth: smooth
                opacity: bind opacity
                effect: effect
            }]
        }
    }
}